Дата арифметика в CMD сценариев

голоса
9

Мне нужно написать скрипт, чтобы изменить имя файла из aDate.txt в bDate.txt, где:

  • aDate является текущей системной датой в ГГГГММДДЕ формате
  • bDate является текущей системной датой - 1 в ГГГГММДДЕ формате.

Я в настоящее время:

set yy=%date:~6,2%
set mm=%date:~3,2%
set dd=%date:~0,2%
if %date:~6,1%==  set yy=0%yy:~1,1%
if %date:~3,1%==  set mm=0%mm:~1,1%
if %date:~0,1%==  set dd=0%dd:~1,1%
SET sys_date=20%yy%%mm%%dd%
ECHO %sys_date%
REM still have to do this bit properly
SET sys_date_yesterday=%sys_date%a
move %sys_date%.txt %sys_date_yesterday%.txt

но я понятия не имею, как это сделать дата -1 вещь (кроме долго наматывается) вычитаем 1 из дня, и если что = 0, то вычтем одно из месяца и установить день = в последний день нового месяца и так далее в течение многих лет.

Есть идеи?

Задан 10/12/2008 в 09:36
источник пользователем
На других языках...                            


5 ответов

голоса
9

Это также работает:

http://www.robvanderwoude.com/datetiment.php#Yesterday

Это очень полное, что он проверяет реестр для настройки локальных форматов даты и использует те при создании даты вчера.

Ответил 10/12/2008 в 11:24
источник пользователем

голоса
4

Вы должны сделать это трудный путь. Я предлагаю использовать это решение, SteveGTR. Я скопируйте приведенный ниже текст, потому что по крайней мере , по крайней мере , я не всегда могу увидеть решение на этом сайте.


Вот пакетный файл, я разработал вычитать любое количество дней от текущей даты. Он принимает параметр командной строки количества дней. Значение по умолчанию 1 день (вчера):

@echo off

set yyyy=

set $tok=1-3
for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
if "%$d1:~0,1%" GTR "9" set $tok=2-4
for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
 for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
    set %%x=%%u
    set %%y=%%v
    set %%z=%%w
    set $d1=
    set $tok=))

if "%yyyy%"=="" set yyyy=%yy%
if /I %yyyy% LSS 100 set /A yyyy=2000 + 1%yyyy% - 100

set CurDate=%mm%/%dd%/%yyyy%

set dayCnt=%1

if "%dayCnt%"=="" set dayCnt=1

REM Substract your days here
set /A dd=1%dd% - 100 - %dayCnt%
set /A mm=1%mm% - 100

:CHKDAY

if /I %dd% GTR 0 goto DONE

set /A mm=%mm% - 1

if /I %mm% GTR 0 goto ADJUSTDAY

set /A mm=12
set /A yyyy=%yyyy% - 1

:ADJUSTDAY

if %mm%==1 goto SET31
if %mm%==2 goto LEAPCHK
if %mm%==3 goto SET31
if %mm%==4 goto SET30
if %mm%==5 goto SET31
if %mm%==6 goto SET30
if %mm%==7 goto SET31
if %mm%==8 goto SET31
if %mm%==9 goto SET30
if %mm%==10 goto SET31
if %mm%==11 goto SET30
REM ** Month 12 falls through

:SET31

set /A dd=31 + %dd%

goto CHKDAY

:SET30

set /A dd=30 + %dd%

goto CHKDAY

:LEAPCHK

set /A tt=%yyyy% %% 4

if not %tt%==0 goto SET28

set /A tt=%yyyy% %% 100

if not %tt%==0 goto SET29

set /A tt=%yyyy% %% 400

if %tt%==0 goto SET29

:SET28

set /A dd=28 + %dd%

goto CHKDAY

:SET29

set /A dd=29 + %dd%

goto CHKDAY

:DONE

if /I %mm% LSS 10 set mm=0%mm%
if /I %dd% LSS 10 set dd=0%dd%

echo Date %dayCnt% day(s) before %CurDate% is %mm%/%dd%/%yyyy%

Удачи, Стив

Ответил 10/12/2008 в 10:59
источник пользователем

голоса
2

Легко добавлять или вычитать дней с даты с Batch Script Windows,

Вот решение, которое я придумал для расчета даты (сложение или вычитание) с помощью пакетного сценария. Задайте переменные соответственно для ваших нужд, а затем настроить логику как необходимость для ваших нужд, а также. Это работает очень хорошо для моих потребностей, и это все содержащиеся в нем к тому же один пакетный сценарий не слишком много логики.

Для добавления: Вы также можете использовать этот скрипт для добавления количества дней к текущей дате, удалив минус ( -) символ из приведенного ниже пакетного сценария в :DynamicVBSScriptBuildрутине, поэтому там , где вы видите это ,-%MinusDay%,вам просто удалить символ минус , чтобы получить ,%MinusDay%,на каждом из этих линий и теперь MinusDay=значение переменной будет равно числу дней , которые вы хотите добавить.

Важное замечание: кажется , что пяти 9 - х ( 99999) является ограничением на пакетном сценарии при вычитании с MinusDays=значением. Кроме того , кажется , что шесть 9 - х ( 999999) является ограничение на пакетный скрипт при добавлении с MinusDays=значением.

Batch Script

@ECHO ON

::// Minus days is the number of days to subtract from the CURRENT DAY i.e. 2 for minus 2 days or 99999 for minus 99999 days from when it's run
SET MinusDay=2

:: This calls the temp vbs script routine that will be used to set YYYY-MM-DD values for the subtracted days date you specify
CALL :DynamicVBSScriptBuild

FOR /F "TOKENS=*" %%A IN ('cscript//nologo "%YYYYTmpVBS%"') DO SET YYYY=%%A
FOR /F "TOKENS=*" %%A IN ('cscript//nologo "%MMTmpVBS%"') DO SET MM=%%A
FOR /F "TOKENS=*" %%A IN ('cscript//nologo "%DDTmpVBS%"') DO SET DD=%%A

::// Set your web server log file path in the below variable
SET WebServerLogPath=C:\WebServer\Logs

::// Set web server log file name where YYYY MM DD variables are set to the values after the day numbers setup above are subtracted
SET YYYY=%YYYY%
SET MM=%MM%
SET DD=%DD%

ECHO %YYYY%%MM%%DD%
PAUSE

GOTO EOF

:DynamicVBSScriptBuild
SET YYYYTmpVBS=%temp%\~tmp_yyyy.vbs
SET MMTmpVBS=%temp%\~tmp_mm.vbs
SET DDTmpVBS=%temp%\~tmp_dd.vbs
IF EXIST "%YYYYTmpVBS%" DEL /Q /F "%YYYYTmpVBS%"
IF EXIST "%MMTmpVBS%" DEL /Q /F "%MMTmpVBS%"
IF EXIST "%DDTmpVBS%" DEL /Q /F "%DDTmpVBS%"
ECHO dt = DateAdd("d",-%MinusDay%,date) >> "%YYYYTmpVBS%"
ECHO yyyy = Year(dt)                    >> "%YYYYTmpVBS%"
ECHO WScript.Echo yyyy                  >> "%YYYYTmpVBS%"
ECHO dt = DateAdd("d",-%MinusDay%,date) >> "%MMTmpVBS%"
ECHO mm = Right("0" ^& Month(dt),2)     >> "%MMTmpVBS%"
ECHO WScript.Echo mm                    >> "%MMTmpVBS%"
ECHO dt = DateAdd("d",-%MinusDay%,date) >> "%DDTmpVBS%"
ECHO dd = Right("0" ^& Day(dt),2)       >> "%DDTmpVBS%"
ECHO WScript.Echo dd                    >> "%DDTmpVBS%"
GOTO EOF

Дополнительные ресурсы

Ответил 22/07/2016 в 16:48
источник пользователем

голоса
1

Попробуйте с этим кодом, другими словами. Вы можете использовать в качестве подпрограммы сценария или использовать это с вызовом функциями и параметров, чтобы перейти обратно к исходному пакетному файлу:

:: Pass 1st parameter as number of days (whole numbers) to subtract from current day in   date
:: This script is able to subtract days to any date of the current date
:: This script will check for leap years, etc. as well
@echo on
::for /f "tokens=2-4 delims=/ " %%A in ("%date%") do set "mm=%%A" do & set "dd=%%B" do & set "yyyy=%%C"
set "mm=%date:~4,2%" & set "dd=%date:~7,2%" & set "yyyy=%date:~10,4%"
set CurDate=%mm%/%dd%/%yyyy%
set dayCnt=%1
if "%dayCnt%"=="" set dayCnt=1
:: Substract your days here
set /A dd=1%dd% - 100 - %dayCnt%
set /A mm=1%mm% - 100
:CHKDAY
if /I %dd% GTR 0 goto DONE
set /A mm=%mm% - 1
if /I %mm% GTR 0 goto ADJUSTDAY
set /A mm=12
set /A yyyy=%yyyy% - 1
:ADJUSTDAY
if %mm%==1 goto SET31
if %mm%==2 goto LEAPCHK
if %mm%==3 goto SET31
if %mm%==4 goto SET30
if %mm%==5 goto SET31
if %mm%==6 goto SET30
if %mm%==7 goto SET31
if %mm%==8 goto SET31
if %mm%==9 goto SET30
if %mm%==10 goto SET31
if %mm%==11 goto SET30
:: ** Month 12 falls through
:SET31
set /A dd=31 + %dd%
goto CHKDAY
:SET30
set /A dd=30 + %dd%
goto CHKDAY
:LEAPCHK
set /A tt=%yyyy% %% 4
if not %tt%==0 goto SET28
set /A tt=%yyyy% %% 100
if not %tt%==0 goto SET29
set /A tt=%yyyy% %% 400
if %tt%==0 goto SET29
:SET28
set /A dd=28 + %dd%
goto CHKDAY
:SET29
set /A dd=29 + %dd%
goto CHKDAY
:DONE
if /I %mm% LSS 10 set mm=0%mm%
if /I %dd% LSS 10 set dd=0%dd%
echo Date %dayCnt% day(s) before %CurDate% is %mm%/%dd%/%yyyy%
SET DirDate=%mm%/%dd%/%yyyy%
:: The %2 parameter is passed from the calling script as the full path and name of the          file to call back
:: %2 equals %~fnx0
:: The dirdate variable is passed as parameter %1 back to the calling script
Call %2 %dirdate%
GOTO EOF

Я собираюсь искать VB или что-то более эффективное, я до сих пор может включать в себя или звонить из партии, чтобы динамически вычислять даты.

Ответил 11/06/2012 в 05:06
источник пользователем

голоса
1

Мне нужно было что-то, что будет вычитать дни от текущей даты во время проверки високосных, и т.д., и это работало замечательно.

Я просто называю это из тех сценариев, с необходимым параметром (числом дней вычитать), а затем он перезвонит сценарий вызова с заменами и передать параметр обратно в исходный сценарий для модифицированной (вычитает) даты.

Вот примеры:

Сценарий переменной необходимости расчета даты, установленные:

IF "%1"=="" goto modifydate

:modifydate
SET subtractdays=5
SET ModDateScript=\\servershare\path\Called_Scripts\ModDate.cmd
CALL "%ModDateScript%" %subtractdays% "%~fnx0"

Скрипт, который будет вычислять и передавать обратно параметр% moddate% к первоначальному вызывающему сценарию должен быть установлен в качестве переменной для того, чтобы обработать соответствующим образом. Вы просто положить это в конце сценария вы называете изменить / вычитать дни от текущей даты (ModDate.cmd).

SET moddate=%mm%/%dd%/%yyyy%
Call %2 %moddate%
GOTO EOF

Я был в состоянии проверить и определить, что эти строки из оригинального сценария отвечали:

set yyyy=
set $tok=1-3
for /f "tokens=1 delims=.:/-, " %%u in ('date /t') do set $d1=%%u
if "%$d1:~0,1%" GTR "9" set $tok=2-4
for /f "tokens=%$tok% delims=.:/-, " %%u in ('date /t') do (
for /f "skip=1 tokens=2-4 delims=/-,()." %%x in ('echo.^|date') do (
    set %%x=%%u
    set %%y=%%v
    set %%z=%%w
    set $d1=
    set $tok=))
if "%yyyy%"=="" set yyyy=%yy%
if /I %yyyy% LSS 100 set /A yyyy=2000 + 1%yyyy% - 100

Может быть заменены только с этой одной строкой, и она работает точно так же:

FOR /F "tokens=2-4 delims=/ " %%A IN ("%date%") DO SET "mm=%%A" DO (& SET "dd=%%B") DO (& SET "yyyy=%%C")

Пожалуйста, объясните, что эти линии (те, я изменил только одной линии с и заявления) делать в любом случае, потому что я не могу сказать разницу быстро тестирования. Я вычитают к 19-м веке, и оказалось, с точностью до меня. Я думал, что, возможно, это помогло справиться расчеты, где модифицированный год будет меньше, чем 2000 - но я не видел, что если я что-то не хватает.

В противном случае это один сценарий можно смело назвать и передать обратно% мм% /% дд% /% гггг% в качестве параметра для нескольких сценариев, которые нуждаются в их собственных расчетах. Большой и очень эффективное решение партии. Я могу передать аргумент% 1,% 2,% 3 и т.д., и до сих пор используют SETLOCAL в этом сценарии для текущей даты - просто сделать что-то вроде переменной moddate =% 1 и т.д.

И, наконец, я бросаю вызов любого эксперта пакетного сценария для оптимизации этого сценария еще дальше и размещать назад результаты для партии людей, чтобы проверить.

Спасибо, P

Ответил 07/05/2012 в 02:48
источник пользователем

Cookies help us deliver our services. By using our services, you agree to our use of cookies. Learn more